12个Excel函数公式必备整理

　　今天精选出12个excel函数公式，虽然它们不并常用，但需要用时你还真不好搜到，所以赶紧收藏起来吧，以下是小编为大家搜索整理的12个Excel函数公式必备整理，希望能给大家带来帮助!更多精彩内容请及时关注我们应届毕业生考试网!

　　12个Excel函数公式整理篇1

　　1、动态获取A列最后一个数字

　　=LOOKUP(1,0/(A2:A100>0),A2:A100)

　　2、不重复个数公式

　　=SUMPRODUCT(1/COUNTIF(A2:A7,A2:A7))

　　3、提取唯一值公式

　　=IFERROR(INDEX(A:A,SMALL(IF(MATCH(A$2:A$7,A$2:A$7,0)=ROW(A$1:A$6),ROW(A$2:A$7)),ROW(A1))),"")

　　4、中国式排名公式

　　=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

　　5、提取字符串任一位中的数字

　　A1的值为 ABC123.45FE ,截取结果：123.45

　　数组公式：{=LOOKUP(9^9,MID(A1,MATCH(1,MID(A1,ROW(1:9),1)^0,0),ROW(1:9))*1)}

　　6、金额大写转换公式

　　=TEXT(LEFT(RMB(A2),LEN(RMB(A2))-3),"[>0][dbnum2]G/通用格式元;[<0]负[dbnum2]G/通用格式元;;") & TEXT(RIGHT(RMB(A2),2),"[dbnum2]0角0分;;整")

　　7、个人所得税计算公式

　　假如A2中是应税工资，则计算个税公式为：

　　=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)

　　8、一对多查找包含公式

　　=COUNT(FIND({"AAA花苑","CCC龙廷"},A2))

　　9、Vlookup多表查找公式

　　工资表模板中，每个部门一个表。

　　在查询表中，要求根据提供的.姓名，从销售~综合5个工作表中查询该员工的基本工资。

　　方法1：

　　=IFERROR(VLOOKUP(A2,服务!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,综合!A:G,7,0),IFERROR(VLOOKUP(A2,财务!A:G,7,0),IFERROR(VLOOKUP(A2,销售!A:G,7,0),"无此人信息")))))

　　方法2

　　=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"销售";"服务";"人事";"综合";"财务"}&"!a:a"),A2),{"销售";"服务";"人事";"综合";"财务"})&"!a:g"),7,0)

　　10、Sumif多表求和公式

　　工作表名称常常是不规则的，如下图所示

　　分析：

　　首先我们需要用宏表函数取得表名

　　公式 - 名称管理器 - 新建名称 - 在新建名称中输入名称“sh”，然后“引用位置”框中输入公式：

　　=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(now())

　　最终公式为：

　　=SUMPRODUCT((SUMIF(INDIRECT(sh&"!b:b"),D2,INDIRECT(sh&"!c:c"))))

　　11、筛选后连续序号公式

　　插入辅助列，输入公式 =1。加入这列是方便在序号列使用公式统计行数。

　　在序号列输入公式

　　=SUBTOTAL(2,B$1:B2)

　　12、用QQ聊天的excel公式

　　=HYPERLINK("tencent://Message/?websiteName=qzone.qq.com&Menu=yes&Uin="&C3,"点击联系他")

　　12个Excel函数公式整理篇2

　　一、数字处理

　　1、取绝对值

　　=ABS(数字)

　　2、取整

　　=INT(数字)

　　3、四舍五入

　　=ROUND(数字,小数位数)

　　二、判断公式

　　1、把公式产生的错误值显示为空

　　公式：C2

　　=IFERROR(A2/B2,"")

　　说明：如果是错误值则显示为空，否则正常显示。

　　2、IF多条件判断返回值

　　公式：C2

　　=IF(AND(A2<500,B2="未到期"),"补款","")

　　说明：两个条件同时成立用AND,任一个成立用OR函数。

　　三、统计公式

　　1、统计两个表格重复的内容

　　公式:B2

　　=COUNTIF(Sheet15!A:A,A2)

　　说明：如果返回值大于0说明在另一个表中存在，0则不存在。

　　2、统计不重复的总人数

　　公式：C2

　　=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

　　说明:用COUNTIF统计出每人的出现次数，用1除的方式把出现次数变成分母，然后相加。

【12个Excel函数公式必备整理】相关文章：

excel表格怎么用subtotal函数10-08

excel中rank函数如何使用09-16

计算机一级：《Excel表格的基本操作》函数和公式编辑技巧09-30

2003excel乘法函数怎么用10-02

12个Excel函数公式整理

12个Excel函数公式整理 篇1

12个Excel函数公式整理 篇2

　　12个Excel函数公式整理篇1

　　12个Excel函数公式整理篇2